# po2tbl.sed.in is invalid on MSDOS
s|po2tbl\.sed\.in|po2tblsed.in|g

# Additional editing of Makefiles and atconfig
/ac_given_INSTALL=/,/^CEOF/ {
  /^CEOF$/ i\
# DJGPP specific Makefile changes.\
  /^aliaspath *	*=/s,:,";",g\
  /TEXINPUTS=/s,:,";",g\
  /PATH=/s,:,";",g\
  s,\\.old\\.,_old.,g\
  s,po2tbl\\.sed\\.in,po2tblsed.in,g\
  s,config\\.h\\.in,config.h-in,g\
  s,Makefile\\.in\\.in,Makefile.in-in,g\
  s,Makefile\\.am\\.in,Makefile.am-in,g\
  /^install-info-am:/,/^$/ {\
    /@list=/ s,\\\$(INFO_DEPS),& recode.i,\
    /@for *file/ s,\\\$(INFO_DEPS),& recode.i,\
    s,file-\\[0-9\\]\\[0-9\\],& \\$\\$file[0-9] \\$\\$file[0-9][0-9],\
  }
}

# Makefile.in.in is renamed to Makefile.in-in...
/^CONFIG_FILES=/,/^EOF/ {
  s|po/Makefile\.in|&:po/Makefile.in-in|
}

# ...and config.h.in into config.h-in
/^ *CONFIG_HEADERS=/,/^EOF/ {
  s|config\.h|&:config.h-in|
}

# Replace (command) > /dev/null with `command > /dev/null`, since
# parenthesized commands always return zero status in the ported Bash,
# even if the named command doesn't exist
/if ([^|;]*null/{
  s,(,`,
  s,),,
  s,;  *then,`; then,
}

# DOS-style absolute file names should be supported as well
/\*) srcdir=/s,/\*,[\\\\/]* | [A-z]:[\\\\/]*,
/\$]\*) INSTALL=/s,\[/\$\]\*,[\\\\/$]* | [A-z]:[\\\\/]*,
/\$]\*) ac_rel_source=/s,\[/\$\]\*,[\\\\/$]* | [A-z]:[\\\\/]*,

# Switch the order of the two Sed commands, since DOS path names
# could include a colon
/ac_file_inputs=/s,\( -e "s%\^%\$ac_given_srcdir/%"\)\( -e "s%:% $ac_given_srcdir/%g"\),\2\1,

# Prevent the spliting of conftest.subs.
# The sed script: conftest.subs is split into 48 or 90 lines long files.
# This will produce sed scripts called conftest.s1, conftest.s2, etc.
# that will not work if conftest.subs contains a multi line sed command
# at line #90. In this case the first part of the sed command will be the
# last line of conftest.s1 and the rest of the command will be the first lines
# of conftest.s2. So both script will not work properly.
# This matches the configure script produced by Autoconf 2.12
/ac_max_sed_cmds=[0-9]/ s,=.*$,=`sed -n "$=" conftest.subs`,
# This matches the configure script produced by Autoconf 2.14a
/ac_max_sed_lines=[0-9]/ s,=.*$,=`sed -n "$=" $ac_cs_root.subs `,

# gettext.m4 (serial 5) from GNU gettext 0.10.35 has a bug.
# When the package is configured with --without-included-gettext option
# and the system libintl.a is found then the LIBS variable *MUST* be set to -lintl
# so that this one is used for linking.
/echo.*\$gt_cv_func_gettext_libintl/,/^EOF$/ {
  /^fi$/ a\
	     if test "$gt_cv_func_gettext_libintl" = yes; then\
	       LIBS="$LIBS -lintl -liconv"\
	     fi
}

# We prefer gettext__ instead of gettext.
/checking for gettext in libintl/,/^EOF$/ s,gettext[ 	]*(,gettext__(,g

# The following two items are changes needed for configuring
# and compiling across partitions.
# 1) The given srcdir value is always translated from the
#    "x:" syntax into "/dev/x" syntax while we run configure.
/^[ 	]*-srcdir=\*.*$/ a\
    ac_optarg=`echo "$ac_optarg" | sed "s,^\\([A-Za-z]\\):,/dev/\\1,"`
/set X `ls -Lt \$srcdir/ i\
   if `echo $srcdir | grep "^/dev/" - > /dev/null`; then\
     srcdir=`echo "$srcdir" | sed -e "s%^/dev/%%" -e "s%/%:/%"`\
   fi

#  2) We need links across partitions, so we will use "cp -pf" instead of "ln".
/# Make a symlink if possible; otherwise try a hard link./,/EOF/ {
  s,;.*then, 2>/dev/null || cp -pf \$srcdir/\$ac_source \$ac_dest&,
}

# DJGPP's port of gettext 0.10.36 makes use of libiconv.a to recode
# on the fly .gmo files from UNIX charset to MSDOS codepage. This implies
# that in all link phases, -liconv MUST be added to -lintl.
/bindtextdomain[ 	]*in[ 	]*-lintl/,/failed[ 	]*program[ 	]*was:/ s,eval[ 	]*\$ac_link,& -liconv,
/gettext[ 	]*in[ 	]*libintl/,/failed[ 	]*program[ 	]*was:/ s,eval[ 	]*\$ac_link,& -liconv,
# /gettext[ 	]*in[ 	]*-lintl/,/failed[ 	]*program[ 	]*was:/ s,eval[ 	]*\$ac_link,& -liconv,