# Configure template for GNU shar utilities.
# Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
# Process this file with autoconf to produce a configure script.

# FIXME: AC_HAVE_HEADERS(sys/time.h)
# FIXME: AC_HAVE_FUNCS(gethostname getwd)

AC_INIT(src/shar.c)
AM_INIT_AUTOMAKE(sharutils,4.2c)
AM_CONFIG_HEADER(config.h:config.h-in)

changequote(,)dnl
case $VERSION in
  [0-9]*.[0-9]*.[0-9]*) DIST_ALPHA="README-alpha";;
  *) DIST_ALPHA=;;
esac
changequote([, ])dnl
AC_SUBST(DIST_ALPHA)

dnl Set of available languages.
ALL_LINGUAS="de fr ja_JP_EUC nl no no@nynorsk pt sv"

AC_ARG_PROGRAM

ADD_PROG=
ADD_SCRIPT="mail-files mailshar"
MAN1PAGES=
MAN5PAGES=
AC_SUBST(ADD_PROG)
AC_SUBST(ADD_SCRIPT)
AC_SUBST(MAN1PAGES)
AC_SUBST(MAN5PAGES)

AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_PROG_RANLIB

dnl FIXME: Check that it is GNU diff indeed.
# Carefully avoid gdiff for X as found on SGI systems.
if (DISPLAY= gdiff /dev/null /dev/null) 2> /dev/null; then
  AC_PATH_PROGS(DIFF, gnudiff diffgnu gdiff diff, no)
else
  AC_PATH_PROGS(DIFF, gnudiff diffgnu diff, no)
fi

dnl FIXME: Check that mailer accepts -s.
PATH_save="$PATH"; PATH="$PATH:/usr/sbin:/usr/ucb:/usr/bin:/bin"
AC_PATH_PROGS(MAILER, Mail mailx elm mush mail, no)
PATH="$PATH_save"

dnl FIXME: Check that perl was found.
AC_PATH_PROG(PERL, perl, no)

AC_PATH_PROGS(SH, bash sh, no)

dnl FIXME: Check that it is GNU tar indeed.
AC_PATH_PROGS(TAR, gnutar targnu gtar tar, tar)

test $ac_cv_path_PERL = no || ADD_SCRIPT="$ADD_SCRIPT remsync"

AC_AIX
AC_ISC_POSIX
AC_MINIX
AM_PROG_CC_STDC
if test $cross_compiling = no; then
  AC_C_CHAR_UNSIGNED
fi
AC_C_CONST
AC_C_INLINE
AC_C_BIGENDIAN

AC_CHECK_HEADERS(limits.h locale.h memory.h string.h sys/wait.h unistd.h fcntl.h sys/fcntl.h)
AC_HEADER_DIRENT
AC_HEADER_STAT
AC_HEADER_STDC
AC_STRUCT_TIMEZONE
AC_TYPE_SIZE_T

AC_CHECK_FUNCS(basename fchmod getcwd isascii memcpy strchr strerror uname)
AC_FUNC_ALLOCA
AC_FUNC_CLOSEDIR_VOID
AC_FUNC_STRFTIME
AC_FUNC_VPRINTF
AC_REPLACE_FUNCS(memset mktime stpcpy strftime)
test "$ac_cv_func_basename" = yes || LIBOBJS="$LIBOBJS basename.o"

AC_MSG_CHECKING(for /etc/systemid)
if test -f /etc/systemid; then
  AC_MSG_RESULT(yes)
  AC_DEFINE(HAVE_ETC_SYSTEMID)
else
  AC_MSG_RESULT(no)
fi

AC_MSG_CHECKING(if uuencode and uudecode are wanted)
AC_ARG_ENABLE(uucode,
[  --disable-uucode        disable installation of uuencode and uudecode],
[if test "$enableval" = yes; then
  AC_MSG_RESULT(yes)
  ADD_PROG="uudecode uuencode"
  MAN1PAGES="uuencode.1 uudecode.1"
  MAN5PAGES="uuencode.5"
else
  AC_MSG_RESULT(no)
fi], [
  AC_MSG_RESULT(yes)
  ADD_PROG="uudecode uuencode"
  MAN1PAGES="uuencode.1 uudecode.1"
  MAN5PAGES="uuencode.5"
])

AM_GNU_GETTEXT
AM_WITH_DMALLOC

AC_OUTPUT([Makefile src/mail-files src/mailshar src/remsync contrib/Makefile \
	   lib/Makefile intl/Makefile intl/po2tbl.sed src/Makefile \
	   po/Makefile.in doc/Makefile tests/Makefile],
[sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile; \
 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])