# po2tbl.sed.in is invalid on MSDOS
s|po2tbl\.sed\.in|po2tblsed.in|g

# Additional editing of Makefiles
/ac_given_INSTALL=/,/^CEOF/ {
  /^s%@l@%/a\
  /TEXINPUTS=/s,:,';',g\
  /PATH=/s,:,';',g\
  /^	@for file in \\\$(INFO_DEPS)/s,\\\$(INFO_DEPS),& tar.i?,\
  s,po2tbl\\.sed\\.in,po2tblsed.in,g\
  s,config\\.h\\.in,config.h-in,g\
  s,intlh\\.inst\\.in,intlh_inst.in,g\
  s,Makefile\\.in\\.in,Makefile.in-in,g\
  s,Makefile\\.am\\.in,Makefile.am-in,g
}

# Makefile.in.in is renamed to Makefile.in-in...
/^CONFIG_FILES=/,/^EOF/ {
  s|po/Makefile\.in |po/Makefile.in:po/Makefile.in-in |
}

# ...and config.h.in into config.h-in
/^ *CONFIG_HEADERS=/,/^EOF/ {
  s|config\.h\([" ]\)$|config.h:config.h-in\1|
}

s|intlh\.inst\.in|intlh_inst.in|g

# DOS-style absolute file names should be supported as well
/\*) srcdir=/s,/\*,/*|[A-z]:/*,
/\$]\*) INSTALL=/s,\[/\$\]\*,&|[A-z]:/*,
/\$]\*) ac_rel_source=/s,\[/\$\]\*,&|[A-z]:/*,
/\*)$/s,/\*,/*|[A-z]:/*,
/^  *if test "x$srcdir" != "x\."; then/,/^  *rm -f po\/POTFILES/c\
      case "$srcdir" in\
   .) \
     posrcprefix="../" ;;\
   /* | [A-Za-z]:*)\
     posrcprefix="$srcdir/" ;;\
   *)\
     posrcprefix="../$srcdir/" ;;\
   esac\
      rm -f po/POTFILES


# Switch the order of the two Sed commands, since DOS path names
# could include a colon
/ac_file_inputs=/s,\( -e "s%\^%\$ac_given_srcdir/%"\)\( -e "s%:% $ac_given_srcdir/%g"\),\2\1,