# DJGPP specific configuration file.
# Sed script for additional DJGPP specific editing
# of the configure script generated by autoconf 2.62.


# Additional editing of Makefiles
/^eval sed.*ac_file_inputs.*tmp\/out \\$/ {
:loop
n
/^$/!b loop
a\
cat > "$tmp/subs-djgpp.sed" << eof_djgpp\
# DJGPP specific Makefile changes.\
s,\\.deps,_deps,g\
s,\\.libs,_libs,g\
s,\\.new\\.,_new.,g\
s,\\.old\\.,_old.,g\
s,\\.tab\\.,_tab.,g\
s,Makefile\\.am\\.in,Makefile.am-in,g\
s,Makefile\\.in\\.in,Makefile.in-in,g\
/^install-info-am:/,/^$/ {\
  /@list=.\\\$(INFO_DEPS)\[^ \]/s,DEPS),& texinf- texin- info-stn.i info.inf,\
  s,\\(\\\$\\\$d/\\\$\\\$file-\\[0-9\\]\\[0-9\\]\\)\\(\[^ \]\\),\\1 \\$\\$d/\\$\\$file[0-9] \\$\\$d/\\$\\$file[0-9][0-9]\\2,\
  s,\\( \\\$\\\$file-\\[0-9\\]\\[0-9\\]\\)\\(\[^ \]\\),\\1 \\$\\$file[0-9] \\$\\$file[0-9][0-9]\\2,\
}\
/^uninstall-info-am:/,/^$/ {\
  /@list=.\\\$(INFO_DEPS)\[^ \]/s,DEPS),& texinf- texin- info-stn.i info.inf,\
  s,\\(file-\\[0-9\\]\\[0-9\\]\\)\\(\[^ \]\\),\\1 \\$\\$file[0-9] \\$\\$file[0-9][0-9]\\2,\
}\
/^gl_LIBOBJS[ 	]*=/s/$/ libsupp_towlower.o libsupp_towupper.o libsupp_mblen.o libsupp_mbrtowc.o libsupp_mbsinit.o libsupp_mbtowc.o/\
/^gl_LTLIBOBJS[ 	]*=/s/$/ libsupp_towlower.lo libsupp_towupper.lo libsupp_mblen.lo libsupp_mbrtowc.lo libsupp_mbsinit.lo libsupp_mbtowc.lo/\
/^libgnu.a[	]*:/i\\\\\
\\\\\
libsupp_towlower.\\$(OBJEXT): \\$(top_srcdir)/djgpp/libsupp_towlower.c\\\\\
	\\$(COMPILE) -c -o \\$@ \\$<\\\\\
libsupp_towupper.\\$(OBJEXT): \\$(top_srcdir)/djgpp/libsupp_towupper.c\\\\\
	\\$(COMPILE) -c -o \\$@ \\$<\\\\\
libsupp_mblen.\\$(OBJEXT): \\$(top_srcdir)/djgpp/libsupp_mblen.c\\\\\
	\\$(COMPILE) -c -o \\$@ \\$<\\\\\
libsupp_mbrtowc.\\$(OBJEXT): \\$(top_srcdir)/djgpp/libsupp_mbrtowc.c\\\\\
	\\$(COMPILE) -c -o \\$@ \\$<\\\\\
libsupp_mbsinit.\\$(OBJEXT): \\$(top_srcdir)/djgpp/libsupp_mbsinit.c\\\\\
	\\$(COMPILE) -c -o \\$@ \\$<\\\\\
libsupp_mbtowc.\\$(OBJEXT): \\$(top_srcdir)/djgpp/libsupp_mbtowc.c\\\\\
	\\$(COMPILE) -c -o \\$@ \\$<\\\\\
\
# /^am_libtxi_a_OBJECTS[ 	]*=/s/=[	 ]*/= libsupp_towlower.\\$(OBJEXT) libsupp_towupper.\\$(OBJEXT) libsupp_mblen.\\$(OBJEXT) libsupp_mbrtowc.\\$(OBJEXT) libsupp_mbsinit.\\$(OBJEXT) libsupp_mbtowc.\\$(OBJEXT) /\
# /^libtxi_a_SOURCES[ 	]*=/s/=[	 ]*/= libsupp_towlower.c libsupp_towupper.c libsupp_mblen.c libsupp_mbrtowc.c libsupp_mbsinit.c libsupp_mbtowc.c /\
# /^libtxi.a[	]*:/i\\\\\
# \\\\\
# libsupp_towlower.\\$(OBJEXT): \\$(top_srcdir)/djgpp/libsupp_towlower.c\\\\\
# 	\\$(COMPILE) -c \\$<\\\\\
# libsupp_towupper.\\$(OBJEXT): \\$(top_srcdir)/djgpp/libsupp_towupper.c\\\\\
# 	\\$(COMPILE) -c \\$<\\\\\
# libsupp_mblen.\\$(OBJEXT): \\$(top_srcdir)/djgpp/libsupp_mblen.c\\\\\
# 	\\$(COMPILE) -c \\$<\\\\\
# libsupp_mbrtowc.\\$(OBJEXT): \\$(top_srcdir)/djgpp/libsupp_mbrtowc.c\\\\\
# 	\\$(COMPILE) -c \\$<\\\\\
# libsupp_mbsinit.\\$(OBJEXT): \\$(top_srcdir)/djgpp/libsupp_mbsinit.c\\\\\
# 	\\$(COMPILE) -c \\$<\\\\\
# libsupp_mbtowc.\\$(OBJEXT): \\$(top_srcdir)/djgpp/libsupp_mbtowc.c\\\\\
# 	\\$(COMPILE) -c \\$<\\\\\
# \
eof_djgpp\
sed -f "\$tmp/subs-djgpp.sed" \$tmp/out > \$tmp/out.djgpp\
mv -f \$tmp/out.djgpp \$tmp/out
}


# Makefile.in.in is renamed to Makefile.in-in.
/ac_config_files=/,/_ACEOF/ {
  s|po/Makefile\.in|&:po/Makefile.in-in|
}
/CONFIG_FILES=/ s|po/Makefile\.in|&:po/Makefile.in-in|2

# We always use _deps and _libs instead of .deps and .libs, because
# the latter is an invalid name on 8+3 MS-DOS file system.  This makes
# the generated Makefiles good for every DJGPP installation, not only
# the one where the package was configured (which could happen to be
# a Windows box, where leading dots in file names are allowed).
/^rmdir[	 ]*\.tst/ i\
am__leading_dot=_

# The following two items are changes needed for configuring
# and compiling across partitions.
# The given srcdir value is always translated from the
# "x:" syntax into "/dev/x" syntax while we run configure.
/^[	 ]*-srcdir=\*.*$/ a\
    ac_optarg=`echo "$ac_optarg" | sed "s,^\\([A-Za-z]\\):,/dev/\\1,"`
/set X `ls -Lt \$srcdir/ i\
   if `echo $srcdir | grep "^/dev/" - > /dev/null`; then\
     srcdir=`echo "$srcdir" | sed -e "s%^/dev/%%" -e "s%/%:/%"`\
   fi

# Autoconf 2.52e generated configure scripts
# write absolute paths into Makefiles making
# them useless for DJGPP installations for which
# the package has not been configured for.
/MISSING=/,/^$/ {
  /^fi$/ a\
am_missing_run=`echo "$am_missing_run" | sed 's%/dev.*/texinfo-\\{0,1\\}4\\.[0-9][0-9]\\{0,1\\}\\.\\{0,1\\}[0-9]\\{0,2\\}[a-z]\\{0,1\\}%${top_srcdir}%;s%.:.*/texinfo-\\{0,1\\}4\\.[0-9][0-9]\\{0,1\\}\\.\\{0,1\\}[0-9]\\{0,2\\}[a-z]\\{0,1\\}%${top_srcdir}%'`
}
/^install_sh=/a\
install_sh=`echo "$install_sh" | sed 's%/dev.*/texinfo-\\{0,1\\}4\\.[0-9][0-9]\\{0,1\\}\\.\\{0,1\\}[0-9]\\{0,2\\}[a-z]\\{0,1\\}%${top_srcdir}%;s%.:.*/texinfo-\\{0,1\\}4\\.[0-9][0-9]\\{0,1\\}\\.\\{0,1\\}[0-9]\\{0,2\\}[a-z]\\{0,1\\}%${top_srcdir}%'`

# On DOS/WIN systems every partition has its own root directory,
# so do not make any assumptions about absolute paths or the
# configure script and the generated Makefiles will only be
# good for the system where the package has been configured for.
/^ac_abs_srcdir=/ i\
ac_abs_builddir=`echo "$ac_abs_builddir" | sed "s%/dev/.*/texinfo[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%;s%.:.*/texinfo[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%"`\
ac_abs_top_builddir=`echo "$ac_abs_top_builddir" | sed "s%/dev/.*/texinfo[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%;s%.:.*/texinfo[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%"`\
ac_abs_top_srcdir=`echo "$ac_abs_top_srcdir" | sed "s%/dev/.*/texinfo[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%;s%.:.*/texinfo[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%"`
#ac_abs_srcdir=`echo "$ac_abs_srcdir" | sed "s%/dev/.*/texinfo[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%;s%.:.*/texinfo[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%"`
/^ac_abs_srcdir=/ a\
for dj_dir in $ac_abs_builddir $ac_abs_top_builddir $ac_abs_top_srcdir $ac_abs_srcdir\
do\
  ac_abs_builddir=`echo "$ac_abs_builddir" | sed "s%//%/%g"`\
  ac_abs_top_builddir=`echo "$ac_abs_top_builddir" | sed "s%//%/%g"`\
  ac_abs_top_srcdir=`echo "$ac_abs_top_srcdir" | sed "s%//%/%g"`\
  ac_abs_srcdir=`echo "$ac_abs_srcdir" | sed "s%//%/%g"`\
done

# The following makes sure we are not going to remove a directory
# which is the cwd on its drive (DOS doesn't allow to remove such
# a directory).  The trick is to chdir to the root directory on
# temp directory's drive before removing $tmp.
/^ *trap 'exit_status=\$\?; rm -rf/s%rm -rf%cd $tmp; cd /; &%

# AC_CONFIG_LINKS fails if the source and destination are on
# different file systems and symlinks don't work.
/^    ln \$srcdir/s%||%|| cp -pf $srcdir/$ac_source $ac_dest ||%

# The CR test for awk does not work for DJGPP.
/^ac_cs_awk_cr=/,/^$/ {
  /^fi$/ a\
ac_cs_awk_cr=$ac_cr
}

# Remove LINGUAS from dependecy list in ./po/Makefile
/POMAKEFILEDEPS=/ s/POMAKEFILEDEPS LINGUAS/POMAKEFILEDEPS #LINGUAS/